C++/スクリプト/言語仕様/式 のバックアップソース(No.5)

• バックアップ一覧
• 差分 を表示
• 現在との差分 を表示
• 現在との差分 - Visual を表示
• バックアップ を表示
• C++/スクリプト/言語仕様/式 へ行く。
  • 1 (2009-11-04 (水) 23:29:22)
  • 2 (2009-11-05 (木) 00:21:52)
  • 3 (2009-11-05 (木) 00:39:31)
  • 4 (2009-11-05 (木) 23:13:18)
  • 5 (2009-11-05 (木) 23:13:18)
  • 6 (2009-11-08 (日) 15:44:26)
  • 7 (2009-11-08 (日) 15:44:26)
  • 8 (2009-11-08 (日) 15:44:26)
  • 9 (2009-11-08 (日) 15:44:26)
  • 10 (2009-11-08 (日) 15:44:26)

* 式 [#dc9e1708]
#contents

** 演算子優先順位 [#a79fdee2]
- 上にあるほど優先が高い。
- ほぼCと同じ。
- 諸事情により一部の演算子は全角文字で記述してあります

|カテゴリ|C演算子|オリジナル|h
|subscript|[ ]||
|postfix|++ --||
|unary_prefix|++ -- + - ! ~ ( )||
|arithmetic_multiplicative|* / %||
|arithmetic_additive|+ -||
|shift|>> <<||
|comparison_relational|< <= > >=||
|comparison_equality|== !=||
|bitwise_and|&||
|bitwise_xor|＾||
|bitwise_or|｜||
|boolean_and|&&||
|boolean_or|｜｜||
|conditional|? :||
|assignment|= += -= *= /= %= >>= <<= &= ｜= ^=||
|sequence|,||

** ExpressionのEBNF [#abe280b9]
#code(){{
UnaryOperator:
   "+"
  | "-"
  | "!"
  | "~"
  | "@"  

PrefixOperator:
  "++"
  | "--"

NewExpression:
  "new" IdentPath FunctionCallExpression

PrimaryExpression:
  IdentPath
  | NewExpression
  | ConstantLiteral
  | "(" Expression ")"

IndexExpression:
  "[" Expression "]"

FunctionCallExpression:
  "(" SequenceExpression ")"

PostfixOperator:
  "++"
  | "--"
  | IndexExpression
  | FunctionCallExpression

PostfixExpression:
  PrimaryExpression (PostfixOperator)*

UnaryExpression:
  UnaryOperator CastExpression
  | (PrefixOperator)* PostfixExpression

CastExpression:
  ( "cast" "(" IdentPath ")" )* UnaryExpression

MultiplicativeOperator:
  "*"
  | "/"
  | "%"

MultiplicativeExpression:
  CastExpression (MultiplicativeOperator CastExpression)*

AdditiveOperator:
  "+"
  | "-"

AdditiveExpression:
  MultiplicativeExpression (AdditiveOperator MultiplicativeExpression)*

ShiftOperator:
  ">>"
  | "<<"

ShiftExpression:
  AdditiveExpression (ShiftOperator AdditiveExpression)*

RelationalOperator:
  ">"
  | "<"
  | "<="
  | ">="

RelationalExpression:
  ShiftExpression (RelationalOperator ShiftExpression)*

EqualityOperator:
  "=="
  | "!="

EqualityExpression:
  RelationalExpression (EqulityOperator RelationalExpression)*

BitwiseAndOperator:
  "&"

BitwiseAndExpression:
  EqualityExpression (BitwiseAndOperator EqualityExpression )* 

BitwiseXorOperator:
  "^"

BitwiseXorExpression:
  BitwiseAndExpression (BitwiseXorOperator BitwiseAndExpression)*
  

BitwiseOrOperator:
  "|"

BitwiseOrExpression:
  BitwiseXorExpression (BitwiseOrOperator BitwiseXorExpression)*
  

LogicalAndOperator:
  "&&"

LogicalAndExpression:
  BitwiseOrExpression (LogicalAndOperator BitwiseOrExpression)*
    
LogicalOrOperator:
  "||"

LogicalOrExpression:
  LogicalAndExpression (LogicalOrOperator LogicalAndExpression)*
  
ConditionalExpression:
  LogicalOrExpression ("?" ConditionalExpression ":" ConditionalExpression)*

AssignmentOperator:
  "="
  | "+="
  | "-="
  | "*="
  | "/="
  | "%="
  | ">>="
  | "<<="
  | "&="
  | "|="
  | "^="

AssignmentExpression:
  (VariableReference AssignmentOperator)* ConditionalExpression

Expression:
  AssignmentExpression

SequenceOperator:
  ","

SequenceExpression:
  AssignmentExpression (SequenceOperator AssignmentExpression)*

}}